radio/audio.scd

// SVNVimStart

s = Server.local;
s.waitForBoot {
    var module, msg, modules;

    // Connect to OSC
    thisProcess.openUDPPort(5005);
    n = NetAddr.new("0.0.0.0", 5005);
    o = OSCFunc({ arg msg, time, addr, recvPort; [msg, time, addr, recvPort].postln; }, '/radio', n);

    // Create the synth definition and load it
    module = SynthDef.new(\module, { 
        arg hue, saturation, value, pan, gain, octave;
        var oscillator, noise, filter, panner, mixer, frequency, qfactor, noise_level, osc_level, lagtime, output, dust;

        // Dynamic time of the module
        lagtime = 100 / (2**octave);

        // Oscillator/filter frequency
        frequency = 130 + (hue * 130) * (2 ** octave);
        frequency = Lag.kr(frequency, lagtime);
        
        // Filtered saw oscillator
        oscillator = SawDPW.ar(frequency);
        filter = DFM1.ar(oscillator, frequency*0.5, 0.8, 1.0, 0.0, 0.0006);

        // Noise
        qfactor = Lag.kr((1 - saturation)**4, lagtime);
        noise = Crackle.ar(1.99, 1.0);
        noise = BPF.ar(noise, frequency, qfactor);

        // Mix noise and saw
        mixer = Mix.ar([filter * saturation, noise*(1-saturation)]);

        // Apply pan
        panner = LinPan2.ar(mixer, pan);

        // Apply dynamics
        output = panner * Lag.kr(HPF.kr(value, 4 * hue / (lagtime)), lagtime);

        // Compress
        output = Compander.ar(output, output, 0.5, 0.3, 0.3, 0.1, lagtime);

        // Crank everything down
        output = output * 0.1; 

        Out.ar(0, output);
    });
    module.load(s);
    s.sync;

    // Create multiple sound generators
    modules = Array.fill(12, 
        {
            arg index; 
            var pan, octave;
            pan = 0 - ((index % 4) - 1.5)/1.5;
            octave = (2 - (index / 4).floor) * 2;
            "Module %: Pan %, octave %\n".postf(index, pan.round(1e-1), octave.round(1e-1));
            Synth.new(\module, 
                [\hue, 0.5, \saturation, 0.1, \value, 0.5, \pan, pan, \gain, 0.9, \octave, octave]
            )
        }
    );


    // Hook up OSC
    f = { |msg, time, addr|
        if(msg[0] == '/radio') {
            if(msg[1]<modules.size){
                modules[msg[1]].set(\hue, msg[2]);
                modules[msg[1]].set(\saturation, msg[3]);
                modules[msg[1]].set(\value, msg[4]);
            }
        }
    };
    thisProcess.addOSCRecvFunc(f);
};